- Postsubmit
- Postsubmit + Current Bazel Incompatible Flags
This repository is the home of the core Python rules -- py_library,
py_binary, py_test, and related symbols that provide the basis for Python
support in Bazel. It also contains packaging rules for integrating with PyPI
(pip). Documentation lives in the
docs/
directory and in the
Bazel Build Encyclopedia.
Currently the core rules are bundled with Bazel itself, and the symbols in this
repository are simple aliases. However, in the future the rules will be
migrated to Starlark and debundled from Bazel. Therefore, the future-proof way
to depend on Python rules is via this repository. SeeMigrating from the Bundled Rules below.
The core rules are stable. Their implementation in Bazel is subject to Bazel's backward compatibility policy. Once they are fully migrated to rules_python, they may evolve at a different rate, but this repository will still follow semantic versioning.
The packaging rules (pip_install, etc.) are less stable. We may make breaking
changes as they evolve. There are no guarantees for rules underneath the
experimental/ directory.
This repository is maintained by the Bazel community. Neither Google, nor the Bazel team, provides support for the code. However, this repository is part of the test suite used to vet new Bazel releases. See the How to contribute page for information on our development workflow.
To import rules_python in your project, you first need to add it to your
WORKSPACE file:
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
http_archive(
name = "rules_python",
url = "https://github.com/bazelbuild/rules_python/releases/download/0.2.0/rules_python-0.2.0.tar.gz",
sha256 = "778197e26c5fbeb07ac2a2c5ae405b30f6cb7ad1f5510ea6fdac03bded96cc6f",
)To depend on a particular unreleased version (not recommended), you can do:
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
rules_python_version = "c8c79aae9aa1b61d199ad03d5fe06338febd0774" # Latest @ 2020-10-15
http_archive(
name = "rules_python",
sha256 = "5be9610a959772697f57ec66bb58c8132970686ed7fb0f1cf81b22ddf12f5368",
strip_prefix = "rules_python-{}".format(rules_python_version),
url = "https://github.com/bazelbuild/rules_python/archive/{}.zip".format(rules_python_version),
)Once you've imported the rule set into your WORKSPACE using any of these
methods, you can then load the core rules in your BUILD files with:
load("@rules_python//python:defs.bzl", "py_binary")
py_binary(
name = "main",
srcs = ["main.py"],
)The packaging rules create two kinds of repositories: A central repo that holds
downloaded wheel files, and individual repos for each wheel's extracted
contents. Users only need to interact with the central repo; the wheel repos
are essentially an implementation detail. The central repo provides a
WORKSPACE macro to create the wheel repos, as well as a function to call in
BUILD files to translate a pip package name into the label of a py_library
target in the appropriate wheel repo.
To add pip dependencies to your WORKSPACE load
the pip_install function, and call it to create the
individual wheel repos.
load("@rules_python//python:pip.bzl", "pip_install")
# Create a central repo that knows about the dependencies needed for
# requirements.txt.
pip_install(
name = "my_deps",
requirements = "//path/to:requirements.txt",
)Note that since pip is executed at WORKSPACE-evaluati
A13D
on time, Bazel has no
information about the Python toolchain and cannot enforce that the interpreter
used to invoke pip matches the interpreter used to run py_binary targets. By
default, pip_install uses the system command "python3". This can be overridden by passing the
python_interpreter attribute or python_interpreter_target attribute to pip_install.
You can have multiple pip_installs in the same workspace, e.g. for Python 2
and Python 3. This will create multiple central repos that have no relation to
one another, and may result in downloading the same wheels multiple times.
As with any repository rule, if you would like to ensure that pip_install is
re-executed in order to pick up a non-hermetic change to your environment (e.g.,
updating your system python interpreter), you can completely flush out your
repo cache with bazel clean --expunge.
One pain point with pip_install is the need to download all dependencies resolved by
your requirements.txt before the bazel analysis phase can start. For large python monorepos
this can take a long time, especially on slow connections.
pip_parse provides a solution to this problem. If you can provide a lock
file of all your python dependencies pip_parse will translate each requirement into its own external repository.
Bazel will only fetch/build wheels for the requirements in the subgraph of your build target.
There are API differences between pip_parse and pip_install:
pip_parserequires a fully resolved lock file of your python dependencies. You can generate this usingpip-compile, or a virtualenv andpip freeze.pip_parseuses a label argument calledrequirements_lockinstead ofrequirementsto make this distinction clear.pip_parsetranslates your requirements into a starlark macro calledinstall_deps. You must call this macro in your WORKSPACE to declare your dependencies.
load("@rules_python//python:pip.bzl", "pip_parse")
# Create a central repo that knows about the dependencies needed from
# requirements_lock.txt.
pip_parse(
name = "my_deps",
requirements_lock = "//path/to:requirements_lock.txt",
)
# Load the starlark macro which will define your dependencies.
load("@my_deps//:requirements.bzl", "install_deps")
# Call it to define repos for your requirements.
install_deps()The deprecated pip_import can still be used if needed.
load("@rules_python//python/legacy_pip_import:pip.bzl", "pip_import", "pip_repositories")
# Create a central repo that knows about the dependencies needed for requirements.txt.
pip_import( # or pip3_import
name = "my_deps",
requirements = "//path/to:requirements.txt",
)
# Load the central repo's install function from its `//:requirements.bzl` file, and call it.
load("@my_deps//:requirements.bzl", "pip_install")
pip_install()
An example can be found in examples/legacy_pip_import.
Each extracted wheel repo contains a py_library target representing the
wheel's contents. Rather than depend on this target's label directly -- which
would require hardcoding the wheel repo's mangled name into your BUILD files --
you should instead use the requirement() function defined in the central
repo's //:requirements.bzl file. This function maps a pip package name to a
label.
load("@my_deps//:requirements.bzl", "requirement")
py_library(
name = "mylib",
srcs = ["mylib.py"],
deps = [
":myotherlib",
requirement("some_pip_dep"),
requirement("another_pip_dep"),
]
)For reference, the wheel repos are canonically named following the pattern:
@{central_repo_name}_pypi__{distribution}_{version}. Characters in the
distribution and version that are illegal in Bazel label names (e.g. -, .)
are replaced with _. While this naming pattern doesn't change often, it is
not guaranted to remain stable, so use of the requirement() function is recommended.
When using the legacy pip_import, you must specify the extra in the argument to the requirement macro. For example:
py_library(
name = "mylib",
srcs = ["mylib.py"],
deps = [
requirement("useful_dep[some_extra]"),
]
)If using pip_install or pip_parse, any extras specified in the requirements file will be automatically
linked as a dependency of the package so that you don't need to specify the extra. In the example above,
you'd just put requirement("useful_dep").
If you need to depend on the wheel dists themselves, for instance to pass them
to some other packaging tool, you can get a handle to them with the whl_requirement macro. For example:
filegroup(
name = "whl_files",
data = [
whl_requirement("boto3"),
]
)The core rules are currently available in Bazel as built-in symbols, but this
form is deprecated. Instead, you should depend on rules_python in your
WORKSPACE file and load the Python rules from
@rules_python//python:defs.bzl.
A buildifier
fix is available to automatically migrate BUILD and .bzl files to add the
appropriate load() statements and rewrite uses of native.py_*.
# Also consider using the -r flag to modify an entire workspace.
buildifier --lint=fix --warnings=native-py <files>Currently the WORKSPACE file needs to be updated manually as per Getting
started above.
Note that Starlark-defined bundled symbols underneath
@bazel_tools//tools/python are also deprecated. These are not yet rewritten
by buildifier.