Опис3D-Link.PNG	Two curves with linking number 4. L8a14. Created with POV-Ray.
Датум	7. септембар 2007., 06:56 (првобитни датум слања)
Извор	Пребачено са en.wikipedia на Оставу. by Keyi (разговор · доприноси).
Аутор	Jim.belk
Дозвола (Поновно коришћење ове датотеке)	Public domainPublic domainfalsefalse   Ово дело је њен носилац ауторских права Jim.belk at the енглески Википедија project предао у јавно власништво. Ово се односи на цео свет. У случају да ово није правно могуће: Jim.belk творац овог дела дозвољава свакоме да користи ово дело за било коју намену, без било каквих услова, осим услова које намеће закон. .

Made with POVRay for Windows, version 3.6.

#include "colors.inc"

#declare AxisLength = 3;
#declare FrameWidth = 0.01;

global_settings { assumed_gamma 1.0}
plane { <0,0,1>, -0.5 pigment {color rgb <.9,.9,.9> } finish {ambient 0.4 diffuse 0.5} }
camera { location <0.1,0.5,4.5> sky <0,0,1> right <-1,1,0>/sqrt(2) look_at <0,0,0> }
light_source { <0, -2, 10> color White area_light <1, 0, 0>, <0, 1, 0>, 3, 3 adaptive 1 jitter }

#declare R = 1.5;  // radius to center circle of torus
#declare r = 0.5;  // radius of torus cross-section  
#declare r_tube = 0.1;  // thickness of tube
              
#macro tpoint(theta,phi)
  <(R + r*cos(phi))*cos(theta), (R + r*cos(phi))*sin(theta), r*sin(phi)>
#end

sphere_sweep
  {
  cubic_spline 35,
  #declare Index = 0;
  #while(Index < 35)
    tpoint( (Index-1)*pi/16, (Index-1)*pi/4), r_tube
    #declare Index = Index + 1;
  #end
  finish {phong 1} pigment {color Blue}
  }

sphere_sweep
  {
  cubic_spline 35,
  #declare Index = 0;
  #while(Index < 35)
    tpoint( (Index-1)*pi/16, (Index+3)*pi/4), r_tube
    #declare Index = Index + 1;
  #end
  finish {phong 1} pigment {color Red}
  }

Complied to 600 x 600, with 0.3 anti-aliasing