build.gradle

/*
 * Copyright (c) 2018 seleniumQuery authors
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

apply plugin: 'java'
apply plugin: 'idea'

idea {
    module {
        downloadJavadoc = true
        downloadSources = true
    }
}

group = 'io.github.seleniumquery'
version = '0.20.0'

description = "seleniumQuery"

ext {
    seleniumVersion = '3.141.59'
    htmlUnitDriverVersion = '2.33.3'
    webDriverManagerVersion = '2.2.5'
}

sourceCompatibility = 1.8
targetCompatibility = 1.8
//noinspection GroovyAssignabilityCheck
tasks.withType(JavaCompile) {
	options.encoding = 'UTF-8'
}

repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    compile('net.sourceforge.cssparser:cssparser:0.9.25')
    compile('org.apache.commons:commons-text:1.3')
    compile('org.apache.commons:commons-lang3:3.7')
    compile("org.seleniumhq.selenium:htmlunit-driver:${htmlUnitDriverVersion}")
    compile("org.seleniumhq.selenium:selenium-api:${seleniumVersion}")
    compile("org.seleniumhq.selenium:selenium-java:${seleniumVersion}")
    compile("org.seleniumhq.selenium:selenium-remote-driver:${seleniumVersion}")
    compile("com.codeborne:phantomjsdriver:1.4.4") {
        exclude(module: 'selenium-java')
        exclude(module: 'selenium-remote-driver')
    }
    compile('commons-logging:commons-logging:1.2')
    compile('org.unbescape:unbescape:1.1.6.RELEASE')

    // used by driverbuilders in the .autoDriverDownload() methods
    compile("io.github.bonigarcia:webdrivermanager:${webDriverManagerVersion}")

    // used by .waitUntil().text().that(<hamcrest matcher>)
    compile("org.hamcrest:hamcrest-library:1.3")

    testCompile('junit:junit:4.12') {
        exclude(module: 'hamcrest-core')
    }
    testCompile('org.hamcrest:hamcrest-junit:2.0.0.0')
}

// https://docs.gradle.org/current/userguide/jacoco_plugin.html
// https://docs.codecov.io/docs/supported-languages --> https://github.com/codecov/example-gradle
apply plugin: "jacoco"
jacoco {
    toolVersion = "0.7.9"
}
jacocoTestReport {
    reports {
        //noinspection GroovyAssignabilityCheck
        xml.enabled true
        //noinspection GroovyAssignabilityCheck
        html.enabled false
    }
}
check.dependsOn jacocoTestReport